var n:int, m:int;
var range:int = 100;
for(var i:int = 1; i <= range; i ++){
  n = 1;
  while(true){
    if(n > i / n){
      break;
    }
    if(i % n == 0){
      if(i / n == n){
        trace("结果",i);
        break;
      }
    }
    n ++;
  }
}

var n:int = 1, range:int = 1000;
for(var i:int = 1; i <= range; i += n = 1){
  while(n > 0) n = n > i / n ? 0 : !(i % n) ? i / n == n ? -1 : n + 1 : n + 1;
  if(n == -1) trace("结果",i);
}

var range:int = 1000000000;
var num:int = Math.pow(range,0.5);
for(var i:int = 1; i <= num; i ++){
  trace("结果",i * i)
}

package
{
  import fl.transitions.Tween;
  import fl.transitions.easing.Bounce;
  
  import flash.display.Bitmap;
  import flash.display.Sprite;
  import flash.events.MouseEvent;

  public class TestShow extends Sprite
  {
    [Embed (source="1.jpg")]
    private var Pic:Class;
    
    private var btn:Sprite;
    private var centerX:int;
    private var centerY:int;
    
    public function TestShow()
    {
      init();
    }
    
    //初始化
    private function init():void{
      centerX = stage.stageWidth / 2;
      centerY = stage.stageHeight / 2;
      
      btn = new Sprite;
      btn.graphics.beginFill(0,0.5);
      btn.graphics.drawRect(centerX - 10,0,20,10);
      btn.graphics.endFill();
      btn.buttonMode = true;
      stage.addChild(btn);
      
      btn.addEventListener(MouseEvent.CLICK,clickHandle);
    }
    
    //点击创建
    private function clickHandle(e:MouseEvent):void{
      var width:int = stage.stageWidth;
      var height:int = stage.stageHeight;
      for(var i:int = 0; i <= 8; i ++){
        var x:int = centerX,y:int = centerY;
        if(i == 4) continue;
        if(i % 3 == 0) x = 0;
        else if(i % 3 == 2) x = width;
        if(i < 3) y = 0;
        else if(i > 5) y = height;
        create(x,y);
      }
    }
    
    //创建一个
    private function create(x:int,y:int):void{
      var spr:Sprite = new Sprite;
      var pic:Bitmap = new Pic;
      pic.x = - pic.width / 2;
      pic.y = - pic.height / 2;
      spr.addChild(pic);
      spr.x = centerX;
      spr.y = centerY;
      setAnimation(spr,x,y);
      addChild(spr);
    }
    
    //创建动画
    private function setAnimation(spr:Sprite,x:int,y:int):void{
      var tweenX:Tween = new Tween(spr,"x",Bounce.easeOut,spr.x,x,50);
      var tweenY:Tween = new Tween(spr,"y",Bounce.easeOut,spr.y,y,50);
    }
  }
}

private var spr:Sprite = new Sprite;
private function func():void{
  var a:Sprite = spr;
}

//创建动画
private function setAnimation(spr:Sprite,x:int,y:int):void{
  var tweenX:Tween = new Tween(spr,"x",Bounce.easeOut,spr.x,x,50);
  var tweenY:Tween = new Tween(spr,"y",Bounce.easeOut,spr.y,y,50);
}

protected function startEnterFrame():void
{
  if (isNaN(this._fps))
  {
    // original frame rate dependent way
    _mc.addEventListener(Event.ENTER_FRAME, this.onEnterFrame, false, 0, true);
  }
  else
  {
    // custom frame rate
    var milliseconds:Number = 1000 / this._fps;
    this._timer.delay = milliseconds;
  this._timer.addEventListener(TimerEvent.TIMER, this.timerHandler, false, 0, true);
  this._timer.start();
  }
  this.isPlaying = true;
}

private function clickHandle(e:MouseEvent):void{
  if(e.currentTarget is Sprite){
    e.updateAfterEvent()
    (e.currentTarget as Sprite).visible = false;
  }
}

e.updateAfterEvent()(e.currentTarget as Sprite).visible = false;

package
{
  import flash.events.Event;

  public class MyEvent extends Event
  {
    public static const MY:String = "my";
    
    public function MyEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
    {
      super(type, bubbles, cancelable);
    }
    
  }
}

addEventListener(MyEvent.MY,myHandle);
private function myHandle(e:MyEvent):void{
  spr.dispatchEvent(e);
}

spr.addEventListener(MyEvent.MY,myHandle);
private function myHandle(e:MyEvent):void{
  trace(e);
}

<?xml version="1.0" encoding="utf-8"?>
<mx:Window xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="init()"
  type="utility" systemChrome="none" showFlexChrome="false" transparent="true"
  width="{main.width}" height="{main.height}" maximizable="false" minimizable="false" resizable="false"
  verticalScrollPolicy="off" horizontalScrollPolicy="off" xmlns:menu="fireas.air.menu.*"
  closing="checkClose(event)">
  <mx:Script>
    <![CDATA[
      import flash.utils.getTimer;
      import fireas.air.menu.MenuProxyEvent;
      import fireas.air.menu.MenuProxy;
      import mx.events.CollectionEvent;
      import mx.core.IUITextField;
      import mx.collections.ArrayCollection;
      
      [Embed (source="../source/16.png")]
      private var ICON:Class;
      
      [Bindable]
      private var recordList:ArrayCollection = new ArrayCollection;
      
      private var tray:SystemTrayIcon;
      
      //初始化
      private function init():void{
        tray = NativeApplication.nativeApplication.icon as SystemTrayIcon;
        tray.addEventListener(ScreenMouseEvent.CLICK,showThis);
        tray.tooltip = "点击显示SimpleDay主窗口";
        tray.bitmaps = [new ICON];
        
        alwaysInFront = true;
        setMainFieldFocus();
        getData();
        
        recordList.addEventListener(CollectionEvent.COLLECTION_CHANGE,function():void{
          updateRecord();
        });
        stage.addEventListener(KeyboardEvent.KEY_UP,function(event:KeyboardEvent):void{
          if(event.keyCode == Keyboard.ENTER) addRecord();
        });
      }
      
      //显示窗口
      private function showThis(e:ScreenMouseEvent):void{
        visible = true;
        nativeWindow.activate();
      }
      
      //获取数据
      private function getData():void{
        var file:File = new File(File.applicationDirectory.resolvePath("data.sdb").nativePath);
        if(file.exists){
          var fileBytes:ByteArray = new ByteArray;
          var source:Array = recordList.source;
          var stream:FileStream = new FileStream;
          stream.open(file,FileMode.READ);
          stream.readBytes(fileBytes);
          stream.close();
          fileBytes.position = 0;
          while(fileBytes.bytesAvailable){
            source.push({label:readByteByLength(fileBytes)});
          }
          recordList.source = source;
        }
        updateRecord();
      }
      
      //文本焦点
      private function setMainFieldFocus(o:Object = null):void{
        mainField.setFocus();
      }
      
      //更新list的高度和布局
      private function updateRecord():void{
        var length:int = recordList.source.length;
        recordComp.height = length * recordComp.rowHeight + 10;
        recordComp.includeInLayout = length > 0;
        
        rightMenu.getForID("close").enabled = !Boolean(length)
      }
      
      //弹出右键菜单
      private function popupRightMenu(event:MouseEvent):void{
        var target:IUITextField = event.target as IUITextField;
        if(target) if(target.selectable) return;
        rightMenu.menu.display(stage,event.stageX,event.stageY)
      }
      
      //检查是否能关闭
      private function checkClose(event:Event):void{
        if(recordList.source.length > 0){
          event.preventDefault();
        }
      }
      
      //添加一个记录
      private function addRecord():void{
        var text:String = mainField.text;
        if(text){
          var source:Array = recordList.source;
          source.push({label:text});
          recordList.source = source;
          mainField.text = "";
        }
      }
      
      //删除一个记录
      private function deleteRecord(index:int):void{
        var source:Array = recordList.source;
        source.splice(index,1);
        recordList.source = source;
        recordList.refresh();
      }
      
      //保存记录到本地
      private function saveData():void{
        var source:Array = recordList.source;
        var fileBytes:ByteArray = new ByteArray;
        for(var i:int = 0; i < source.length; i ++){
          var bytes:ByteArray = getByteByString(source[i].label);
          fileBytes.writeBytes(bytes);
        }
        var file:File = new File(File.applicationDirectory.resolvePath("data.sdb").nativePath);
        var stream:FileStream = new FileStream;
        stream.open(file,FileMode.WRITE);
        stream.writeBytes(fileBytes);
        stream.close();
        new HTMLLoader().window.alert("保存成功！");
      }
      
      //按长度写字符串
      private function getByteByString(text:String):ByteArray{
        var result:ByteArray = new ByteArray;
        result.writeShort(0);
        result.writeUTFBytes(text);
        result.position = 0;
        result.writeShort(result.length - 2);
        return result;
      }
      
      //按长度读字符串
      private function readByteByLength(bytes:ByteArray):String{
        var length:int = bytes.readUnsignedShort();
        return bytes.readUTFBytes(length);
      }
      
      //处理右键菜单
      private function rightMenuSelectHandle(e:MenuProxyEvent):void{
        switch(e.mark){
          case "lock":
            var b:Boolean = e.menu.checked;
            e.menu.checked = !b;
            recordComp.mouseEnabled =
            recordComp.mouseChildren = b;
          break;
          case "close":
            NativeApplication.nativeApplication.exit();
          break;
          case "save":
            saveData();
          break;
          case "hide":
            visible = false;
          break;
        }
      }
    ]]>
  </mx:Script>
  <menu:MenuProxy id="rightMenu" mark="rightMenuSelectHandle(event)">
    <menu:menuData>
      <mx:XML xmlns="">
        <root>
          <item label="锁定日志" select="lock"/>
          <item label="隐藏窗口" select="hide"/>
          <item label="保存" select="save"/>
          <item id="close" label="关闭" select="close"/>
        </root>
      </mx:XML>
    </menu:menuData>
  </menu:MenuProxy>
  <mx:VBox id="main" verticalGap="0" mouseDown="nativeWindow.startMove()"
    rightClick="popupRightMenu(event)">
    <mx:Panel width="300" height="50" borderColor="0" borderAlpha="0.7" cornerRadius="15"
      headerHeight="10" dropShadowEnabled="false">
      <mx:HBox width="100%" height="100%" horizontalGap="0" borderStyle="solid" borderColor="0x909090"
        borderThickness="2" mouseDown="event.stopPropagation()">
        <mx:TextInput id="mainField" width="100%" height="100%" fontSize="18" fontWeight="bold"
          focusThickness="0" focusOut="setMainFieldFocus()" borderStyle="solid" borderThickness="0"/>
        <mx:Canvas backgroundColor="0xcfdfff" height="100%">
          <mx:LinkButton icon="@Embed('../source/add.png')" height="100%" cornerRadius="0"
            click="addRecord()"/>
        </mx:Canvas>
      </mx:HBox>
    </mx:Panel>
    <mx:List id="recordComp" width="100%" dataProvider="{recordList}" borderThickness="0"
      backgroundColor="0" color="0xffffff" backgroundAlpha="0.7" paddingLeft="10" paddingRight="10"
      change="recordComp.selectedIndex = -1" itemClick="deleteRecord(event.rowIndex)"
      dragEnabled="true" dragMoveEnabled="true" dropEnabled="true" mouseDown="event.stopPropagation()"/>
  </mx:VBox>
</mx:Window>

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
  applicationComplete="init()">
  <mx:Style>
    Window{
      fontFamily:"宋体";
      fontSize:12;
    }
  </mx:Style>
  <mx:Script>
    <![CDATA[
      import code.MainWindow;
      
      private function init():void{
        nativeApplication.autoExit = false;
        close();
        
        new MainWindow().open();
      }
    ]]>
  </mx:Script>
</mx:WindowedApplication>